# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Luca Weiss <luca (at) z3ntu (dot) xyz>
# Contributor: Gabriele Musco <emaildigabry@gmail.com>

pkgname=(
  openrazer-daemon
  openrazer-driver-dkms
  python-openrazer
)
pkgbase=openrazer
pkgver=3.11.0
pkgrel=1
pkgdesc='Community-led effort to support Razer peripherals on Linux'
arch=(any)
url=https://openrazer.github.io
license=(GPL)
makedepends=(
  git
  python-setuptools
)
source=("git+https://github.com/$pkgbase/$pkgbase.git#tag=v$pkgver")
b2sums=('1de999028896195de90a95cbf8c2a5f3d265a02942d3a2a035b46a2e580d72d22df45a8cb360121819fe39a6fa5206a2b0901cc7766888a947fb668377bd36b4')

package_openrazer-daemon() {
  pkgdesc='Userspace daemon that abstracts access to the kernel driver. Provides a DBus service for applications to use'
  depends=(
    dbus-python
    openrazer-driver-dkms
    python-daemonize
    python-gobject
    python-pyudev
    python-setproctitle
    xautomation
  )
  optdepends=('libnotify: for the battery notifier')
  install=$pkgbase-daemon.install

  cd $pkgbase
  make DESTDIR="$pkgdir" daemon_install
}

package_openrazer-driver-dkms() {
  pkgdesc='OpenRazer kernel modules sources'
  depends=(dkms)

  cd $pkgbase
  make DESTDIR="$pkgdir" setup_dkms udev_install
}

package_python-openrazer() {
  pkgdesc='Library for interacting with the OpenRazer daemon'
  depends=(
    openrazer-daemon
    python-numpy
  )

  cd $pkgbase
  make DESTDIR="$pkgdir" python_library_install
}
