# Maintainer: Felix Yan <felixonmars@archlinux.org>

pkgname=dhall-yaml
pkgver=1.2.12
pkgrel=164
pkgdesc="Convert between Dhall and YAML"
url="https://github.com/dhall-lang/dhall-haskell/tree/master/dhall-yaml"
license=("GPL3")
arch=('x86_64')
depends=('ghc-libs' 'haskell-hsyaml' 'haskell-hsyaml-aeson' 'haskell-aeson' 'haskell-ansi-terminal'
         'dhall' 'dhall-json' 'haskell-optparse-applicative' 'haskell-prettyprinter'
         'haskell-prettyprinter-ansi-terminal' 'haskell-vector')
makedepends=('ghc' 'uusi' 'haskell-tasty' 'haskell-tasty-expected-failure' 'haskell-tasty-hunit')
source=("https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz")
sha512sums=('440e78b5d32979bece9fd4655e8131c65624ed53b2e3f82028eacd39761133e8e64bd4a1cbade0c65281cbc05edbc66f87ab00d4a2e9f3ddbf5fa29f9bcfe356')

prepare() {
  cd $pkgname-$pkgver
  gen-setup
  uusi -u ansi-terminal -u optparse-applicative -u tasty
}

build() {
  cd $pkgname-$pkgver

  runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
    --ghc-option='-pie'
  
  runhaskell Setup build $MAKEFLAGS
  runhaskell Setup register --gen-script
  runhaskell Setup unregister --gen-script
  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
  cd $pkgname-$pkgver
  runhaskell Setup test --show-details=direct
}

package() {
  cd $pkgname-$pkgver

  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  runhaskell Setup copy --destdir="$pkgdir"
  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
}
